Pour ton dernier problème, et quelque soit le langage, voici la solution, évidente quand tu l'auras lue :
Code:
Si Majuscule ( Variable ) = "VALEUR" Alors ...
Si Minuscule ( Variable ) = "valeur" Alors ...
Si Majuscule ( Variable1 ) = Majuscule ( Variable2 ) Alors ...
Si Minuscule ( Variable1 ) = Minuscule ( Variable2 ) Alors ...
Mais peut-être as-tu déjà trouvé, le temps que je te réponde.
_______________________________________________________________________
Quant à ta solution, quelle horreur. Je ne parle pas de la maîtrise du langage, mais de l'algorithme. Pouah !!
En plus il reste des erreurs.
Tu l'as ta zone, tu la définis ligne 7 ! Qu'est-ce que tu nous fais ligne 21 ?
Je te rappelle que
CountA c'est la fonction
NBVAL, et que si tu as un trou dans ta liste, ta boucle est fausse.
Et puis pourquoi deux boucles. Une seule suffit !
Et encore une remarque sous forme de devinettes :
■ Combien y-a-t-il de ligne dans une feuille XL ?
■ Entre quelles valeurs, la valeur d'un entier de type Integer est-elle comprise ?
Ah, j'oubliais. Partout, tu précises la feuille sur laquelle tu travailles. C'est très bien. Comme ça, pas de select, d'activate ou de ce genre de choses qui ralentissent le programme ou qui supposent que l'on doit être dans tel cas particulier pour que ça marche. Sauf que ligne 22, tu l'oublies ! (En plus, c'est au moment de la suppression des lignes. Si tu veux perdre tes données, c'est comme ça qu'il faut faire).
Regarde :
Code:
Dim ws_s As Worksheet
Dim ws_p As Worksheet
Dim rg_s As Range
Dim rg_p As Range
Dim r As Long
Dim last_row As Long
Set ws_s = Worksheets("shipped" )
Set ws_p = Worksheets("produits" )
' // S'il ne doit pas y avoir de trou entre la première valeur et la dernière :
last_row = ws_p.Range("B2" ).End(xlDown).Row
' // S'il peut y avoir des trous :
last_row = ws_p.Range("B65536" ).End(xlUp).Row
For r = last_row To 2 Step -1
If Lcase(ws_p.Range("B" & r).Value) = "deinstall" And _
UCase(ws_p.Range("G" & r).Value) = "DECISIONONE" Then
ws_s.Range("A2").EntireRow.Insert
Set rg_p = ws_p.Range("B" & r)
Set rg_s = ws_s.Range("A2")
ws_s.Range("A2").Value = rg_p.Offset(, 5).Value
ws_s.Range("B2").Value = rg_p.Offset(, 0).Value
ws_s.Range("C2").Value = rg_p.Offset(, 1).Value
ws_s.Range("D2").Value = rg_p.Offset(, 2).Value
ws_s.Range("E2").Value = rg_p.Offset(, 3).Value
ws_s.Range("F2").Value = rg_p.Offset(, 4).Value
ws_s.Range("G2").Value = waybill
ws_s.Range("H2").Value = Now
rg_p.EntireRow.Delete
Enf If
Next
Bon, c'est pas mal, qu'est-ce que t'en penses ?
Moi, je suis un gros fainéant. Je n'aime pas écrire six fois la même chose.
Alors je réécris les lignes 22 à 29 :
Code:
Set rg_s = ws_s.Range("A2")
rg_s.Offset(, 0).Value = rg_p.Offset(, 5).Value
rg_s.Offset(, 1).Value = rg_p.Offset(, 0).Value
rg_s.Offset(, 2).Value = rg_p.Offset(, 1).Value
rg_s.Offset(, 3).Value = rg_p.Offset(, 2).Value
rg_s.Offset(, 4).Value = rg_p.Offset(, 3).Value
rg_s.Offset(, 5).Value = rg_p.Offset(, 4).Value
Code:
Set rg_s = ws_s.Range("A2")
For i = 0 To 5
rg_s.Offset(, i) = rg_p.Offset(, (i + 5) Mod 6 )
Next
rg_s.Offset(, 6).Value = waybill
rg_s.Offset(, 7).Value = Now
Une dernière chose.
La méthode
Range peut accepter une chaîne de caractères et on peut construire l'adresse comme ceci :
Code:
rg_p = ws_p.Range("B" & r)
Ce qui est plus sympa, à première vue, que cela :
Mais s'habituer à la notation (Ligne,Colonne) a l'avantage d'être plus facile à traiter avec des nombres, dans des boucles, par exemple. La preuve, c'est que tant que c'est la ligne qui varie, c'est sympa, mais si c'était sur la colonne qu'il fallait itérer, ferais-tu des choses comme ça :
Code:
For colonne = 1 To 10
Range(Chr(colonne+64)) ..
Next
Surtout pas, parce que le suivant de 'Z', c'est 'AA' pour Excel, et non pas '[' pour l'Ascii.
On reprend le tout :
Code:
Dim ws_s As Worksheet
Dim ws_p As Worksheet
Dim rg_s As Range
Dim rg_p As Range
Dim r As Long
Dim i As Long
Dim last_row As Long
Set ws_s = Worksheets("shipped")
Set ws_p = Worksheets("produits")
' // S'il ne doit pas y avoir de trou entre la première valeur et la dernière :
last_row = ws_p.Cells(2, 2).End(xlDown).Row
' // S'il peut y avoir des trous :
last_row = ws_p.Cells(65536, 2).End(xlUp).Row
For r = last_row To 2 Step -1
If Lcase(ws_p.Cells(r, 2).Value) = "deinstall" And _
UCase(ws_p.Cells(r, 7).Value) = "DECISIONONE" Then
ws_s.Cells(2, 1).EntireRow.Insert
Set rg_p = ws_p.Cells(r, 2)
Set rg_s = ws_s.Cells(2, 1)
For i = 0 To 5
rg_s.Offset(, i) = rg_p.Offset(, (i + 5) Mod 6)
Next
rg_s.Offset(, 6).Value = waybill
rg_s.Offset(, 7).Value = Now
rg_p.EntireRow.Delete
Enf If
Next
TADAAA!
t1cable: 
